
Vix is an Elixir extension for libvips image processing library.
About libvips from its documentation:
libvips is a demand-driven, horizontally threaded image processing library. Compared to similar libraries, libvips runs quickly and uses little memory.


  
    
  
  About Vix


Vix is a NIF based bindings library for libvips.
Major Features:
	Vix can take full advantage of libvips optimizations, such as joining of operations in the pipeline, cache. Since Vix is native binding
	Experimental support for streaming. User can read or write images without keeping complete image in memory. See Vix.Vips.Image.new_from_enum/1 and Vix.Vips.Image.write_to_stream/2
	Efficient interoperability (zero-copy) with other libraries such as Nx, eVision. See Vix.Vips.Image.new_from_binary/5 and Vix.Vips.Image.write_to_tensor/1
	By default vix provides pre built NIF and libvips binaries for major platforms, so you don't have to worry about bringing the libvips dependencies and compiling NIF. Just add vix and you are good to go! See below for more details
	Ergonomic bindings with auto generated documentation for the operations using vips introspection. So they always match the libvips installed. If newer libvips update adds or modify operations, you don't have to wait for vix to be updated, bindings for the operations along with documentation will be available automatically

Check vips operation documentation for the list of available operations and spec.

  
    
  
  Pre-compiled NIF and libvips


Starting from v0.16.0 vix can use either pre-built binaries or platform provided binaries.
By default Vix provides pre-built NIF and libvips and use that for operation. This makes deployment and release of your application a simple. No need to install any compiler toolchain and dependencies to use Vix. Pre-built libvips supports reading SVG, PNG, TIFF, JPEG, WEBP, RAW, HEIF, GIF. If you find that the pre-built libvips is missing support for an image format then you can bring your own libvips by installing it manually and configure vix to use that instead. Vix makes sure to generate relevant functions and documentation based on the dependencies you bring. For example, if you install libvips with dzsave support, vix will generate dzsave bindings for you.
You can choose this using VIX_COMPILATION_MODE env variable. This variable must be set both during compilation and runtime. Possible values are:
	PRECOMPILED_NIF_AND_LIBVIPS (Default): Uses vix provided NIF and libvips. No need to install any additional dependencies. Big thanks to sharp library maintainers, pre-compiled libvips is based on: https://github.com/lovell/sharp-libvips/.
Run this command below to generate the required checksum.exs file.
MIX_ENV=dev mix elixir_make.checksum --all --ignore-unavailable


	PLATFORM_PROVIDED_LIBVIPS: Uses platform provided libvips and NIF will be compiled during compilation phase. You need to install required build tools to compile NIF. To build NIF you need these:
	libvips with development headers	macOS: using brew brew install libvips
	Linux: using deb apt install libvips-dev
For more details see https://www.libvips.org/install.html


	pkg-config
	C compiler



Should I use Vix or Image?
Vix is focused on bridging beam and libvips, and tries to be close to libvips interface to support large set of use cases. Because of this doing some basic operation might feel unintuitive. Image an excellent library by @kipcole9 builds on top of Vix and provides more elixir friendly wrapper functions for common operations along with many additional features such handling Exif, Math operators, and more. And all of this is accompanied by good documentation. So for most of the users, using Vix via Image might be better choice.

  
    
  
  Introduction


Easiest way to get started or to explore the operations is to run Introduction Livebook.
[image: Run in Livebook]
# print vips version
IO.puts("Version: " <> Vix.Vips.version())

# contains image read/write functions
alias Vix.Vips.Image

# reading image from a file. Note that image is not actually loaded to the memory at this point.
# img is `%Image{}` struct.
{:ok, img} = Image.new_from_file("~/Downloads/kitty.png")

# You can also load image from binary. This let us to work images without touching file system.
# It tires to guess image format from the binary and uses correct loader.

bin = File.read!("~/Downloads/kitty.png")
{:ok, %Image{} = img} = Image.new_from_buffer(bin)

# If you know image format beforehand then you can use appropriate function from
# `Vix.Vips.Operation`. For example to load png you can use `Vix.Vips.Operation.pngload_buffer/2`.

bin = File.read!("~/Downloads/kitty.png")
{:ok, {img, _flags}} = Vix.Vips.Operation.pngload_buffer(bin)

# writing `Image` to a file.
# Image type selected based on the image path extension. See documentation for more options
:ok = Image.write_to_file(img, "kitty.jpg[Q=90]")

# let's print image dimensions
IO.puts("Width: #{Image.width(img)}")
IO.puts("Height: #{Image.height(img)}")


# Operations

# contains image processing operations
alias Vix.Vips.Operation

# getting a rectangular region from the image (crop)
{:ok, extract_img} = Operation.extract_area(img, 100, 50, 200, 200)

# create image thumbnail
#
# This operation is significantly faster than normal resize
# due to several optimizations such as shrink-on-load.
# You can read more about it in the libvips docs: https://github.com/libvips/libvips/wiki/HOWTO----Image-shrinking
#
# Check Vix docs for more details about several optional parameters
width = 100
{:ok, thumb} = Operation.thumbnail("~/Downloads/dog.jpg", width)


# resize image to 400x600. `resize` function accepts scaling factor.
# Skip `vscale` if you want to preserve aspect ratio
hscale = 400 / Image.width(img)
vscale = 600 / Image.height(img)
{:ok, resized_img} = Operation.resize(img, hscale, vscale: vscale)

# flip image
{:ok, flipped_img} = Operation.flip(img, :VIPS_DIRECTION_HORIZONTAL)

# Gaussian blur
{:ok, blurred_img} = Operation.gaussblur(img, 5)

# convert image to a grayscale image
{:ok, bw_img} = Operation.colourspace(img, :VIPS_INTERPRETATION_B_W)

# adding gray border
{:ok, extended_img} =
  Operation.embed(img, 10, 10, Image.width(img) + 20, Image.height(img) + 20,
    extend: :VIPS_EXTEND_BACKGROUND,
    background: [128]
  )

# rotate image 90 degree clockwise
{:ok, rotated_img} = Operation.rot(img, :VIPS_ANGLE_D90)

# join two images horizontally
{:ok, main_img} = Image.new_from_file("~/Downloads/kitten.svg")
{:ok, joined_img} = Operation.join(img, main_img, :VIPS_DIRECTION_HORIZONTAL, expand: true)

# render text as image
# see https://libvips.github.io/libvips/API/current/libvips-create.html#vips-text for more details
{:ok, {text, _}} = Operation.text(~s(<b>Vix</b> is <span foreground="red">awesome!</span>), dpi: 300, rgba: true)
# add text to an image
{:ok, img_with_text} = Operation.composite2(img, text, :VIPS_BLEND_MODE_OVER, x: 50, y: 20)


## Creating GIF
black = Operation.black!(500, 500, bands: 3)

# create images with different grayscale
frames = Enum.map(1..255//10, fn n ->
  Operation.linear!(black, [1], [n/255,n/255,n/255])
end)

{:ok, joined_img} = Operation.arrayjoin(frames, across: 1)

# set frame delay metadata. See `Image.mutate` documentation for more details
{:ok, joined_img} =
  Image.mutate(joined_img, fn mut_img ->
    frame_delay = List.duplicate(100, length(frames))
    :ok = Vix.Vips.MutableImage.set(mut_img, "delay", :VipsArrayInt, frame_delay)
  end)

:ok = Operation.gifsave(joined_img, Path.expand("~/Downloads/bw.gif"), "page-height": 500)
The libvips reference manual has more detailed documentation about the operations.

  
    
  
  Livebooks


	Livebook implementing picture language defined in Structural and Interpretation of Computer Programs section 2.2.4.

[image: Run in Livebook]
	Creating Rainbow. Quick introduction to complex number and operations, mapim, buildlut.

[image: Run in Livebook]
	Auto correct Document Rotation. Quick introduction to Fourier Transformation, Complex planes, and Arithmetic Operations.

[image: Run in Livebook]

  
    
  
  NIF Error Logging


Vix NIF code writes logs to stderr on certain errors. This is disabled by default. To enable logging set VIX_LOG_ERROR environment variable to true.

  
    
  
  Installation


def deps do
  [
    {:vix, "~> x.x.x"}
  ]
end


  

    
LICENSE
    


MIT License

Copyright (c) 2020 Akash Hiremath

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.



  

    
Introduction
    

Mix.install([
  {:kino, "~> 0.7.0"},
  {:vix, "~> 0.5"}
])
# print vips version
IO.puts("Version: " <> Vix.Vips.version())

  
    
  
  Vips Image


All image IO operations such as reading and writing files are available in Vix.Vips.Image module. Image module also contains functions get image attributes. Most Vips operations takes %Vix.Vips.Image{} instance
alias Vix.Vips.Image
Reading image from a file. Note that image is not actually loaded to the memory at this point. img is %Image{} struct.
{:ok, %Image{} = img} = Image.new_from_file("~/Downloads/kitty.png")
You can also load image from binary. This let us to work images without touching file system. It tires to guess image format from the binary and uses correct loader.
bin = File.read!("~/Downloads/kitty.png")
{:ok, %Image{} = img} = Image.new_from_buffer(bin)
If you know image format beforehand then you can use appropriate function from Vix.Vips.Operation. For example to load png you can use Vix.Vips.Operation.pngload_buffer/2.
bin = File.read!("~/Downloads/kitty.png")
{:ok, {img, _flags}} = Vix.Vips.Operation.pngload_buffer(bin)
Writing Image to a file. Image type selected based on the image path extension. See documentation for more options
:ok = Image.write_to_file(img, "kitty.jpg[Q=90]")
# let's print image dimensions
IO.puts("Width: #{Image.width(img)}")
IO.puts("Height: #{Image.height(img)}")
Kino supports showing image inline. We can use this to display image in the livebook.
This opens gate for exploratory image processing
defmodule VixExt do
  alias Vix.Vips.Operation

  @max_height 500

  def show(%Image{} = image) do
    height = Image.height(image)

    # scale down if image height is larger than 500px
    image =
      if height > @max_height do
        Operation.resize!(image, @max_height / height)
      else
        image
      end

    # write vips-image as png image to memory
    {:ok, image_bin} = Image.write_to_buffer(image, ".png")
    Kino.render(Kino.Image.new(image_bin, "image/png"))

    :ok
  end
end
import VixExt

# Lets see show in action
show(img)

  
    
  
  Vips Operations


All image processing operations are available in Vix.Vips.Operation
alias Vix.Vips.Operation

  
    
  
  Crop


Getting a rectangular region from the image
{:ok, extract_img} = Operation.extract_area(img, 100, 50, 200, 200)
show(extract_img)

  
    
  
  Thumbnail


This operation is significantly faster than normal resize due to
several optimizations such as shrink-on-load.  You can read more about
it in the libvips docs: https://github.com/libvips/libvips/wiki/HOWTO----Image-shrinking
Check Vix docs for more details about several optional parameters
{:ok, thumb} = Operation.thumbnail("~/Downloads/kitty.png", 100)
show(thumb)

  
    
  
  Resize


Resize image to 400x600. resize function accepts scaling factor.
Skip vscale if you want to preserve aspect ratio
hscale = 400 / Image.width(img)
vscale = 600 / Image.height(img)

{:ok, resized_img} = Operation.resize(img, hscale, vscale: vscale)
show(resized_img)

  
    
  
  Flip


direction_input =
  Kino.Input.select("Direction: ",
    VIPS_DIRECTION_HORIZONTAL: "Horizontal",
    VIPS_DIRECTION_VERTICAL: "Vertical"
  )
direction = Kino.Input.read(direction_input)

{:ok, flipped_img} = Operation.flip(img, direction)
show(flipped_img)

  
    
  
  Text


Text operation takes multiple optional parameters. See libvips doc for more details
text_input = Kino.Input.text("Text: ")
str = String.trim(Kino.Input.read(text_input))
{:ok, {text, _}} = Operation.text(str, dpi: 300, rgba: true)

# add text to an image
{:ok, inserted_text_img} = Operation.composite2(img, text, :VIPS_BLEND_MODE_OVER, x: 50, y: 20)

show(inserted_text_img)

  
    
  
  Creating GIF


black = Operation.black!(500, 500, bands: 3)

# create images with different grayscale
frames = Enum.map(1..255//10, fn n ->
  Operation.linear!(black, [1], [n/255, n/255, n/255])
end)

{:ok, joined_img} = Operation.arrayjoin(frames, across: 1)

{:ok, joined_img} =
  Image.mutate(joined_img, fn mut_img ->
    frame_delay = List.duplicate(100, length(frames))
    :ok = Vix.Vips.MutableImage.set(mut_img, "delay", :VipsArrayInt, frame_delay)
  end)

:ok = Operation.gifsave(joined_img, Path.expand("~/Downloads/bw.gif"), "page-height": 500)

  
    
  
  Few more operations


# Gaussian blur
{:ok, blurred_img} = Operation.gaussblur(img, 5)
show(blurred_img)

# convert image to a grayscale image
{:ok, bw_img} = Operation.colourspace(img, :VIPS_INTERPRETATION_B_W)
show(bw_img)

# adding gray border
{:ok, extended_img} =
  Operation.embed(img, 10, 10, Image.width(img) + 20, Image.height(img) + 20,
    extend: :VIPS_EXTEND_BACKGROUND,
    background: [128]
  )

show(extended_img)

# rotate image 90 degree clockwise
{:ok, rotated_img} = Operation.rot(img, :VIPS_ANGLE_D90)
show(rotated_img)

# join two images horizontally
{:ok, main_img} = Image.new_from_file("~/Downloads/kitten.svg")
{:ok, joined_img} = Operation.join(img, main_img, :VIPS_DIRECTION_HORIZONTAL, expand: true)
show(joined_img)


  

    
Picture Language
    


  
    
  
  Install dependencies


Mix.install([
  {:kino, "~> 0.3.0"},
  {:vix, "~> 0.5"}
])
Defining helper function display using kino so that we can show image inline
defmodule VixExt do
  alias Vix.Vips.Image
  alias Vix.Vips.Operation

  @max_height 500

  def show(%Image{} = image) do
    height = Image.height(image)

    # scale down if image height is larger than 500px
    image =
      if height > @max_height do
        Operation.resize!(image, @max_height / height)
      else
        image
      end

    # write vips-image as png image to memory
    {:ok, image_bin} = Image.write_to_buffer(image, ".png")
    Kino.render(Kino.Image.new(image_bin, "image/png"))

    :ok
  end
end

  
    
  
  Picture Language


Implementing picture language defined in Structural and Interpretation of Computer Programs section 2.2.4 in Elixir using vix
defmodule Pict do
  alias Vix.Vips.Operation, as: Op

  def beside(a, b) do
    Op.resize!(Op.join!(a, b, :VIPS_DIRECTION_HORIZONTAL), 0.5, vscale: 1)
  end

  def below(a, b) do
    Op.resize!(Op.join!(a, b, :VIPS_DIRECTION_VERTICAL), 1, vscale: 0.5)
  end

  def vert_flip(p) do
    Op.flip!(p, :VIPS_DIRECTION_VERTICAL)
  end

  def horz_flip(p) do
    Op.flip!(p, :VIPS_DIRECTION_HORIZONTAL)
  end
end
Implementation of Fig. 2.14
defmodule PictUtils do
  import Pict

  def right_split(p, 0), do: p

  def right_split(p, n) do
    t = right_split(p, n - 1)
    beside(p, below(t, t))
  end

  def up_split(p, 0), do: p

  def up_split(p, n) do
    t = up_split(p, n - 1)
    below(beside(t, t), p)
  end

  def corner_split(p, 0), do: p

  def corner_split(p, n) do
    us = up_split(p, n - 1)
    rs = right_split(p, n - 1)

    beside(
      below(beside(us, us), p),
      below(corner_split(p, n - 1), below(rs, rs))
    )
  end
end
alias Vix.Vips.Image
import VixExt

{:ok, img} = Image.new_from_file("~/Downloads/kitty.png")
img = PictUtils.corner_split(img, 5)

right = Pict.below(img, Pict.vert_flip(img))
left = Pict.horz_flip(right)
img = Pict.beside(left, right)

show(img)


  

    
Creating Rainbow  🌈
    

Mix.install([
  {:vix, "~> 0.22.0"},
  {:kino, "~> 0.10.0"}
])

  
    
  
  Introduction


Libvips provides over 300 image processing operations, but getting the
intuition behind what is possible and how to combine the primitive
image processing operations can be a challenging.
With this notebook we look into some and of the core operations while
trying to achieve a simple goal, which is to generate a rainbow
🌈. Rainbow should have the half-circular arch, there should be a
smooth blend between the colors.

  
    
  
  Generating the colors


First let's look into just generating the rainbow colors. We need to
generate the whole spectrum with the smooth blend between them.
libvips provides buildlut function which generate a pointwise
intermediate values between the provided points. lut here means
Look Up Table. buildlut takes a 1D matrix where each value
represent different points of the format [position, bands] and
buildlut will build a single band, one pixel height image with a
smooth poitwise transition between the points. If you pass [0, 0]
(at position zero pixel value is zero) [255, 255] (at position 255
value is 255), the buildlut will return an image with pixels 0 at
position 0, 1 at position 1, 2 at position 2 etc, ending with
255 at position 255. We can think of it as range 0..255.
alias Vix.Vips.Image
alias Vix.Vips.Operation

# buildlut needs matrix image.
# we can create matrix-image using `Image.new_matrix_from_array` which takes
# list and return an vips-image which can be passed to buildlut
{:ok, mat} = Image.new_matrix_from_array(2, 2, [[0, 0], [255, 255]])

gradient = Operation.buildlut!(mat)
Switch to attributes tab to see more details about the image.
We can see the gradient clearly if we increase the image height
Operation.resize!(gradient, 3, vscale: 50)
buildlut accepts multiple bands as well. So we can generate gradient
for colors too, not just between black and white
defmodule Vix.KinoUtils do
  # Utility to read color and parse hex string into list of
  # 8-bit integers
  def read_colors do
    start_color = Kino.Input.color("Start", default: "#DDDD55")
    end_color = Kino.Input.color("End", default: "#FF2200")

    [start_color, end_color]
    |> Kino.Layout.grid(columns: 6)
    |> Kino.render()

    start_color = read(start_color)
    end_color = read(end_color)

    {start_color, end_color}
  end

  defp read(input) do
    "#" <> color = Kino.Input.read(input)

    for <<hex::binary-size(2) <- color>> do
      String.to_integer(hex, 16)
    end
  end
end

# read user input
{start_color, end_color} = Vix.KinoUtils.read_colors()

{:ok, mat} =
  Image.new_matrix_from_array(4, 2, [
    [0 | start_color],
    [255 | end_color]
  ])

mat
|> Operation.buildlut!()
|> Operation.cast!(:VIPS_FORMAT_UCHAR)
|> Operation.resize!(3, vscale: 50)

# change the `Start` and `End` colors and evaluate
To generate the rainbow colors, the pixel values in RGB colour space
will be [255, 0, 0] (red), [255, 165, 0] (orange) ... [143, 0, 255] (violet). We could generate these values but it is inconvenient to
juggle all 3 bands.
Generating the colors in HSV color space we need [0, 255, 255] (red), [24, 255, 255] (orange) ... [212, 255, 255] (violet). Which is much
nicer to work with, since we only need to change one value.
{:ok, mat} =
  Image.new_matrix_from_array(4, 2, [
    # position 0   - [0,   255, 255]
    [0, 0, 255, 255],
    # position 255 - [255, 255, 255]
    [255, 255, 255, 255]
  ])

gradient = Operation.buildlut!(mat)

# by default the colour space won't be HSV.
# We make a shallow copy and set the colorspace to HSV.
# While also setting band format to `unsigned char`
rainbow_colors =
  Operation.copy!(gradient,
    band_format: :VIPS_FORMAT_UCHAR,
    interpretation: :VIPS_INTERPRETATION_HSV
  )

# resize to make it visible
Operation.resize!(rainbow_colors, 3, vscale: 50)

# notice that the output spectrum starts from RED and ends with RED.
# this is slightly incorrect, since rainbow ends with violet. We'll fix this later

  
    
  
  Generating the Arch


How to generate the half circular arch? there are several way to
approach this but we are going to use complex band format and polar
coordinates.

  
    
  
  Complex Numbers


A pixel on the image has a position represented its x coordinate and y
coordinate. value x represent point position along the width and y
axis along the height, ie. we need 2 values to form a point. In
complex number system a pixel is a single complex number value. A
value in complex number system represents a point on a 2D plane
instead of a value on an axis. You can just think of it as just a
fancy way to represent position on 2D plane. Internally a complex
number is just a pair of Real part and Imaginary part.
There are two different ways to locate a point on 2D plane
	Cartesian coordinate system
	Polar coordinate system

Cartesian coordinate System
Here real part represent x coordinate and imaginary part represents y coordinate.
[image: ]
a and b is used to locate the point z
Polar System
Here real part represents distance from the origin and imaginary part represents angle
[image: ]
Angle φ and distance r is used to locate point z
But why do we need complex number?
Because it makes certain operations simple. Operations which operate
on plane rather than axis. For example, to draw a circle on a polar
plane we only need to vary angle keeping the distance constant.
Lets take an example and see libvips operations on complex
planes. First let's create a image at with its origin at the center of
the image. It makes it easy to understand what is happening.
use Vix.Operator

width = height = 255

# create 200 x 200 matrix where each pixel represent its own position.
# pixel at left-top will be `{0, 0}` (black)
# pixel right-bottom will be `{255, 255}` (white)
xy = Operation.xyz!(width, height)

# Display how axis values are chaining
Kino.Layout.grid([Kino.Text.new("X-Axis"), Kino.Text.new("Y-Axis"), xy[0], xy[1]], columns: 2)
|> Kino.render()

# move origin to center of the image
xy = (xy - [width / 2, height / 2]) * 2

# Display how axis values are changing after moving the origin.
# Notice that origin black pixel starts at top-left before
# and at center after moving the origin
Kino.Layout.grid(
  [Kino.Text.new("Centered X-Axis"), Kino.Text.new("Centered Y-Axis"), xy[0], xy[1]],
  columns: 2
)
Now that we have an image, we can see how it looks in polar plane
# convert band format to complex number format.
# we specify that read 2 bands to form a single complx band.
# x axis becomes the real part of the complex number
# y axis becomes the Imaginary part of the complex number
complex_xy = Operation.copy!(xy, format: :VIPS_FORMAT_COMPLEX, bands: 1)

# change complex number plane to polar plane.
# vips reads complex number and converts that to polar value for all pixels.
# real part will be distance from the origin
# imaginary part will be the angle in degree
polar_xy = Operation.complex!(complex_xy, :VIPS_OPERATION_COMPLEX_POLAR)

# convert the complex number back to 2 band float image.
# x axis is the real part of the complex number
# y asix is the imaginary part of the complex number
xy = Operation.copy!(polar_xy, format: :VIPS_FORMAT_FLOAT, bands: 2)

# angle will be in degree (from 0 to 360), scale it back to 255
xy = xy * [1, height / 360]

Kino.Layout.grid([Kino.Text.new("X-Axis"), Kino.Text.new("Y-Axis"), xy[0], xy[1]], columns: 2)
As you can see x axis is the real part of the complex number, which is
distance from the origin and Y axis is the imaginary part of the
complex number which is the angle.
This is much easier to understand if we draw few line on the input
image. and see how it changes in the polar plane
defmodule ComplexOps do
  def to_polar(img, background \\ [0, 0, 0]) do
    %{width: width, height: height} = Image.headers(img)
    xy = Operation.xyz!(width, height)
    xy = xy - [width / 2, height / 2]

    scale = min(height, width) / width
    xy = xy * 2 / scale

    xy =
      xy
      |> Operation.copy!(format: :VIPS_FORMAT_COMPLEX, bands: 1)
      |> Operation.complex!(:VIPS_OPERATION_COMPLEX_POLAR)
      |> Operation.copy!(format: :VIPS_FORMAT_FLOAT, bands: 2)

    xy = xy * [1, height / 360]

    # mapim takes an input and a `map` and generates an output image
    # where input image pixels are moved based on map.
    #
    # [new_x, new_y] = map[x, y]
    # out[x, y] = img[new_x, new_y]
    #
    # mapim is to rotate, displace, distort, any type of spatial operations.
    # where the pixel value (color) remain same but the position is changed.
    Operation.mapim!(img, xy, background: background)
  end
end

x_line = Operation.black!(10, height) + 255
y_line = Operation.black!(width, 10) + 125

# create a black image and draw 2 lines
# an x axis at 50
# a y axis at 50
img =
  Operation.black!(width, height)
  |> Operation.insert!(x_line, 50, 0)
  |> Operation.insert!(y_line, 0, 50)

# convert img to polar
out = ComplexOps.to_polar(img)

Kino.Layout.grid([Kino.Text.new("Input"), Kino.Text.new("Output"), img, out], columns: 2)
A line on the x axis becomes a circle on the polar plane and a line on
the y axis becomes a line from the origin.
So to draw a rainbow circle we just need to draw a rainbow line on the
x axis and convert that to polar plane!
rainbow_colors
|> Operation.resize!(100 / 255, vscale: 400)
|> Operation.embed!(150, 0, 600, 400)
# wrap moves the image to origin
|> Operation.wrap!()
|> ComplexOps.to_polar()
|> dbg()

# select the stage on the output to see how image transforms
:ok
All that is left now is to make few final adjustments to make it pretty
# create colors from violet to red instead of red to red
{:ok, mat} = Image.new_matrix_from_array(4, 2, [[0, 220, 255, 255], [255, 0, 255, 255]])

rainbow_colors =
  Operation.copy!(Operation.buildlut!(mat),
    band_format: :VIPS_FORMAT_UCHAR,
    interpretation: :VIPS_INTERPRETATION_HSV
  )

sky_color = [135, 100, 255]

rainbow_colors
|> Operation.resize!(100 / 255, vscale: 500)
|> Operation.embed!(50, 0, 500, 500, background: sky_color)
|> Operation.wrap!()
|> ComplexOps.to_polar(sky_color)
# take only top half of the image
|> Operation.copy!(height: 250, width: 500)


  

    
Auto Correct Document Rotation
    

Mix.install(
  [
    {:vix, "~> 0.17.0"},
    {:kino, "~> 0.9.2"}
  ],
  # pre-built binaries does not support fourier transform operations
  # since these operations depend on an additional library.
  #
  # Usually the platform/OS provided libvips comes with these additional library
  # so we are telling vix to use the libvips provided by the platform
  # and compile NIF for that. Follow platform specific libvips
  # installation guide
  system_env: [
    {"VIX_COMPILATION_MODE", "PLATFORM_PROVIDED_LIBVIPS"}
  ]
)

  
    
  
  Introduction


In this livebook we look into correcting the text image rotation using
image processing techniques such as Fourier Transformation, complex
planes, and arithmetic operations.
This notebook is heavily based on libvips blog post
and stack overflow answer.
We use the same image mentioned on the blog to test our implementation.
So let's first fetch the test image.
alias Vix.Vips.Image
alias Vix.Vips.Operation

# import convenience math operators `+`, `-`, `*` etc.
use Vix.Operator

# we use `:httpc` to download the image
{:ok, _} = Application.ensure_all_started(:inets)
{:ok, _} = Application.ensure_all_started(:ssl)

# image link is from the stackoverflow question
image_url = 'https://i.stack.imgur.com/2q4Qr.png'
{:ok, {{_, 200, _}, _headers, bin}} = :httpc.request(:get, {image_url, []}, [timeout: 5000], [])

{:ok, img} =
  bin
  |> IO.iodata_to_binary()
  |> Image.new_from_buffer()

# convert 4 channel PNG image to black & white
img = Operation.colourspace!(img, :VIPS_INTERPRETATION_B_W)
# skip alpha band
img = img[0]
Notice that the image is not fully vertical, orienttion is slightly off

  
    
  
  Fourier Transformation


An image can be expressed as sum of sine and cosine waves of varying
magnitudes, frequency and phase. Fourier Transform is an operation
which decomposes an image into its sine and cosine components.
There are lot of resources online on this topic,
I found this
and this useful get started.
Libvips has fwfft
function for Forward Fourier Transform operation and
invfft
for Inverse Fourier Transform operation.

  
    
  
  Fwfft


fwfft returns an image with complex band format. Real part of the
band will be the wave Amplitude, Imaginary part of the band will be the
wave Phase. Position of the value is the frequency.
Since the returned image is in Complex band format, it can not be displayed.
To make it visible we need convert the complex band to 2 band float, warp the
image to center, scale values so they are visible.
white = Operation.black!(10, 200) + 255
vert_line = Operation.embed!(white, 45, 0, 200, 200)

# take fourier transform of the input image
ft = Operation.fwfft!(vert_line)

# display the images, notice the band format and band count
Kino.Layout.grid(
  [Kino.Text.new("Input"), Kino.Text.new("Fourier Transform"), vert_line, ft],
  columns: 2
)
|> Kino.render()

# convert complex number to 2 band double format
ft = Operation.copy!(ft, format: :VIPS_FORMAT_DOUBLE, bands: 2)

# do logarithm scaling for the image so that points visible
# and move the origin of the image to center
scaled_ft =
  ft
  |> Operation.scale!(log: true)
  |> Operation.wrap!()

# separate amplitude and phase channels
amp = scaled_ft[0]
phase = scaled_ft[1]

Kino.Layout.grid(
  [Kino.Text.new("Amplitude"), Kino.Text.new("Phase"), amp, phase],
  columns: 2
)
Since all these conversion is common, libvips provides
spectrum function which does all this for you.
Spectrum computes fourier transform, takes absolute value
(amplitude), scales and wraps the origin. It meant for
displaying the Fourier Transform.
Operation.spectrum!(vert_line)
Let's display fourier transform for few sample images to see how the
output changes. Change the number of lines and see how fourier transform changes.
lines_count =
  Kino.Input.number("Number of lines", default: 10)
  |> Kino.render()
  |> Kino.Input.read()

# lets create images which black and white lines
width = trunc(100 / lines_count)
black_line = Operation.black!(width, 200)

# 10 lines B&W lines
lines =
  [black_line, Operation.invert!(black_line)]
  |> List.duplicate(lines_count)
  |> List.flatten()

vert_lines = Operation.arrayjoin!(lines, across: length(lines))
horz_lines = Operation.rot!(vert_lines, :VIPS_ANGLE_D90)
vert_horz_lines = vert_lines + horz_lines

samples = [vert_lines, horz_lines, vert_horz_lines]

samples
|> Enum.flat_map(fn img ->
  [img, Operation.spectrum!(img)]
end)
|> Kino.Layout.grid(columns: 2)
As we can see, the vertical lines in the input image produces a horizontal
line in the fourier transform and horizontal lines in the
input produces to vertical line in the FT. Changing the number of lines
does not change the number lines on the output image.
So if we take Fourier Transform of a perfect text image, it should have
vertical lines and or horizontal lines exactly at 0, 90, 180, 270 degree angle,
since the characters and lines are either parallel or perpedicular. If the
document is off by some angle then the same should be visible in the Fourier
Transform.
Kino.Layout.grid([img, Operation.spectrum!(img)], columns: 2)
Indeed we can see a slightly off vertical line and horizontal
lines. Now we just need to find the angle.

  
    
  
  Finding the angle


As said before output of image of Fourier Transform will be in complex band format.
The real part of it is amplitude, which is what we are
seeing as lines and there is imaginary part which is phase.
There are two different way to plot complex numbers on a 2D plane.
	Cartesian (Rectangle) coordinate system
	Polar coordinate system

Libvips provides functions to convert numbers from one plane to other plane.
Intuitively when converting from Cartesian system to Polar system,
all vertical lines becomes the circle and horizontal lines becomes the arch/segment.
Which is what we used in the "Creating Rainbow" livebook for generating the arch.
But there is also the inverse operation. We can convert an image from Polar
plan to Cartesian plane. The circle becomes the vertical line and the
segment becomes the horizontal line. More importantly radius becomes the x-axis and
angle becomes the y-axis.
Let's see few examples
defmodule ComplexOps do
  def to_cartesian(img, background \\ [0, 0, 0]) do
    %{width: width, height: height} = Image.headers(img)
    xy = Operation.xyz!(width, height)

    # normalize the y-axis to be between 0 and 360
    xy = xy * [1, 360 / height]

    xy =
      xy
      # read values as complex numbers
      |> Operation.copy!(format: :VIPS_FORMAT_COMPLEX, bands: 1)
      # convert from polar to Cartesian plane
      |> Operation.complex!(:VIPS_OPERATION_COMPLEX_RECT)
      # and convert back to float
      |> Operation.copy!(format: :VIPS_FORMAT_FLOAT, bands: 2)

    scale = min(width, height) / width
    xy = xy * (scale / 2)
    xy = xy + [width / 2, height / 2]

    # mapim takes an input and a `map` and generates an output image
    # where input image pixels are moved based on map.
    #
    # [new_x, new_y] = map[x, y]
    # out[x, y] = img[new_x, new_y]
    #
    # mapim is to rotate, displace, distort, any type of spatial operations.
    # where the pixel value (color) remain same but the position is changed.
    Operation.mapim!(img, xy, background: background)
  end
end

samples
|> Enum.flat_map(fn img ->
  ft = Operation.spectrum!(img)
  [img, ft, ComplexOps.to_cartesian(ft)]
end)
|> Kino.Layout.grid(columns: 3)
# for the input document
img
|> Operation.spectrum!()
|> ComplexOps.to_cartesian()
Only thing left now is to find a row with maximum value.
The row number corresponding to the maximum value is the angle.
Libvips has project function which finds the row wise and column
wise sum and returns them as image, we can then use max to
find the maximum value and its position.
defmodule Utils do
  def find_angle(cartesian) do
    # find the row wise and column wise sum
    # returns 2 images with respective column/row sum
    {_columns, rows} = Operation.project!(cartesian)

    # find position of the row with maximum value
    {_, %{y: y_pos}} = Operation.max!(rows)

    # convert the y position back to angle.
    y_pos / Image.height(rows) * 360
  end
end

samples
|> Enum.flat_map(fn img ->
  ft = Operation.spectrum!(img)
  cartesian = ComplexOps.to_cartesian(ft)

  angle = Utils.find_angle(cartesian)
  # print angle next to image
  text = Kino.Text.new("\n\n\n#{to_string(angle)}")

  [img, ft, cartesian, text]
end)
|> then(fn list ->
  headers = ~w(Input Fourier-Transform Polar-Plane Angle) |> Enum.map(&Kino.Text.new/1)
  headers ++ list
end)
|> Kino.Layout.grid(columns: 4)
If there are multiple rows with same maximum values we pick one randomly.
For the input image
ft = Operation.spectrum!(img)
cartesian = ComplexOps.to_cartesian(ft)

angle = Utils.find_angle(cartesian)

# since we know that angle can only be parallel or perpendicular
# can take mod of 90
angle = angle - trunc(angle / 90) * 90

  
    
  
  Correcting the rotation


Putting it all together now we can rotate the image using the
difference as correction to fix the document
diff = 90 - angle
corrected = Operation.rotate!(img, diff)

Kino.Layout.grid([Kino.Text.new("Input"), Kino.Text.new("Corrected"), img, corrected], columns: 2)


  

    
Vix.Operator 
    



      
Provides implementation of basic math operators for Vix Image.
Useful to improve the readability of complex Image processing
operation pipelines.
def foo do
  use Vix.Operator

  black = Operation.black!(100, 100, bands: 3)
  white = Operation.invert!(black)

  white == white + black
  grey = black + 125  # same as [125]
  grey = black + [125] # same as [125, 125, 125], since the image contains 3 bands
  grey = black + [125, 125, 125]
end

    Vix.Tensor - vix v0.30.0
    
    

    


  
  

    
Vix.Tensor 
    



      
Struct to hold raw pixel data returned by the libvips along with metadata about the binary.
Useful for interoperability between other libraries like Nx, Evision.
See Vix.Vips.Image.write_to_tensor/1 to convert an vix image to tensor.

    Vix.Vips - vix v0.30.0
    
    

    


  
  

    
Vix.Vips 
    



      
Module for Vix.Vips.

    Vix.Vips.Image - vix v0.30.0
    
    

    


  
  

    
Vix.Vips.Image 
    



      
Functions for reading and writing images as well as
accessing and updating image metadata.

  
    
  
  Access syntax (slicing)


Vix images implement Elixir's access syntax. This allows developers
to slice images and easily access sub-dimensions and values.

  
    
  
  Integer


Access accepts integers. Integers will extract an image band using parameter as index:
#=> {:ok, i} = Image.new_from_file("./test/images/puppies.jpg")
{:ok, %Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153539>}}
#=> i[0]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153540>}
If a negative index is given, it accesses the band from the back:
#=> i[-1]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153540>}
Out of bound access will throw an ArgumentError exception:
#=> i[-4]
** (ArgumentError) Invalid band requested. Found -4

  
    
  
  Range


Access also accepts ranges. Ranges in Elixir are inclusive:
#=> i[0..1]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153641>}
Ranges can receive negative positions and they will read from
the back. In such cases, the range step must be explicitly given
(on Elixir 1.12 and later) and the right-side of the range must
be equal or greater than the left-side:
#=> i[0..-1//1]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153703>}
To slice across multiple dimensions, you can wrap the ranges in a list.
The list will be of the form [with_slice, height_slice, band_slice].
# Returns an image that slices a 10x10 pixel square
# from the top left of the image with three bands
#=> i[[0..9, 0..9, 0..3]]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153738>}
If number of dimensions are less than 3 then remaining dimensions
are returned in full
# If `i` size is 100x100 with 3 bands
#=> i[[0..9, 0..9]] # equivalent to `i[[0..9, 0..9, 0..2]]`
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153740>}

#=> i[[0..9]] # equivalent to `i[[0..9, 0..99, 0..2]]`
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153703>}
Slices can include negative ranges in which case the indexes
are calculated from the right and bottom of the image.
# Slices the bottom right 10x10 pixels of the image
# and returns all bands.
#=> i[[-10..-1, -10..-1]]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153742>}
Slice can mix integers and ranges
# Slices the bottom right 10x1 pixels of the image
# and returns all bands.
#=> i[[-10..-1, -1]]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153742>}

  
    
  
  Keyword List


Access also accepts keyword list. Where key can be any of width,
height, band.  and value must be an integer, range. This is
useful for complex scenarios when you want omit dimensions arbitrary
dimensions.
# Slices an image with height 10 with max width and all bands
#=> i[[height: 0..10]]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153742>}

# Slices an image with single band 1
#=> i[[band: 1]]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153742>}

# Slices the bottom right 10x10 pixels of the image
# and returns all bands.
#=> i[[width: -10..-1, height: -10..-1]]
%Vix.Vips.Image{ref: #Reference<0.2448791511.2685009949.153742>}

Vix.Vips.Interpolate 
    



      
Make interpolators for operators like affine and mapim.

    Vix.Vips.MutableImage - vix v0.30.0
    
    

    


  
  

    
Vix.Vips.MutableImage 
    



      
Vips Mutable Image
See Vix.Vips.Image.mutate/2

    Vix.Vips.MutableOperation - vix v0.30.0
    
    

    


  
  

    
Vix.Vips.MutableOperation 
    



      
Module for Vix.Vips.MutableOperation.

    Vix.Vips.Operation - vix v0.30.0
    
    

    


  
  

    
Vix.Vips.Operation 
    



      
Vips Operations
See libvips
documentation
for more detailed description of the operation.
Vips operation functions are generated using vips-introspection and
are up-to-date with libvips version installed. Documentation in the
hexdocs might not match for you.

Vix.Vips.Image.Error exception

